mirror of
https://github.com/nim-lang/Nim.git
synced 2025-12-30 01:44:37 +00:00
d55bbefdcc
* implemented the with stdlib module as specified in https://github.com/nim-lang/RFCs/issues/193 * change sugar.outplace to sugar.dup according to https://github.com/nim-lang/RFCs/issues/193 * changelog update
59 lines
1.4 KiB
Nim
59 lines
1.4 KiB
Nim
#
|
|
#
|
|
# Nim's Runtime Library
|
|
# (c) Copyright 2020 Andreas Rumpf
|
|
#
|
|
# See the file "copying.txt", included in this
|
|
# distribution, for details about the copyright.
|
|
#
|
|
|
|
## This module implements the ``with`` macro for easy
|
|
## function chaining. See https://github.com/nim-lang/RFCs/issues/193
|
|
## and https://github.com/nim-lang/RFCs/issues/192 for details leading to this
|
|
## particular design.
|
|
##
|
|
## **Since** version 1.2.
|
|
|
|
import macros, private / underscored_calls
|
|
|
|
macro with*(arg: typed; calls: varargs[untyped]): untyped =
|
|
## This macro provides the `chaining`:idx: of function calls.
|
|
## It does so by patching every call in `calls` to
|
|
## use `arg` as the first argument.
|
|
## **This evaluates `arg` multiple times!**
|
|
runnableExamples:
|
|
var x = "yay"
|
|
with x:
|
|
add "abc"
|
|
add "efg"
|
|
doAssert x == "yayabcefg"
|
|
|
|
var a = 44
|
|
with a:
|
|
+= 4
|
|
-= 5
|
|
doAssert a == 43
|
|
|
|
result = newNimNode(nnkStmtList, arg)
|
|
expectKind calls, nnkArgList
|
|
let body =
|
|
if calls.len == 1 and calls[0].kind in {nnkStmtList, nnkStmtListExpr}:
|
|
calls[0]
|
|
else:
|
|
calls
|
|
for call in body:
|
|
result.add underscoredCall(call, arg)
|
|
|
|
when isMainModule:
|
|
type
|
|
Foo = object
|
|
col, pos: string
|
|
|
|
proc setColor(f: var Foo; r, g, b: int) = f.col = $(r, g, b)
|
|
proc setPosition(f: var Foo; x, y: float) = f.pos = $(x, y)
|
|
|
|
var f: Foo
|
|
with(f, setColor(2, 3, 4), setPosition(0.0, 1.0))
|
|
echo f
|
|
|