mirror of
https://github.com/nim-lang/Nim.git
synced 2025-12-29 17:34:43 +00:00
2bd1aa186e
* New/better macro pragmas, make some experimental fix #15920, close #18212, close #14781, close #6696, close https://github.com/nim-lang/RFCs/issues/220 Variable macro pragmas have been changed to only take a unary section node. They can now also be applied in sections with multiple variables, as well as `const` sections. They also accept arguments. Templates now support macro pragmas, mirroring other routine types. Type and variable macro pragmas have been made experimental. Symbols without parentheses instatiating nullary macros or templates has also been documented in the experimental manual. A check for a redefinition error based on the left hand side of variable definitions when using variable macro pragmas was disabled. This nerfs `byaddr` specifically, however this has been documented as a consequence of the experimental features `byaddr` uses. Given how simple these changes are I'm worried if I'm missing something. * accomodate compiler boot * allow weird pragmas * add test for #10994 * remove some control flow, try remove some logic
33 lines
1000 B
Nim
33 lines
1000 B
Nim
# see `semLowerLetVarCustomPragma` for compiler support that enables these
|
|
# lowerings
|
|
|
|
import macros
|
|
|
|
macro byaddr*(sect) =
|
|
## Allows a syntax for l-value references, being an exact analog to
|
|
## `auto& a = ex;` in C++.
|
|
##
|
|
## Warning: This makes use of 2 experimental features, namely nullary
|
|
## templates instantiated as symbols and variable macro pragmas.
|
|
## For this reason, its behavior is not stable. The current implementation
|
|
## allows redefinition, but this is not an intended consequence.
|
|
runnableExamples:
|
|
var s = @[10, 11, 12]
|
|
var a {.byaddr.} = s[0]
|
|
a += 100
|
|
assert s == @[110, 11, 12]
|
|
assert a is int
|
|
var b {.byaddr.}: int = s[0]
|
|
assert a.addr == b.addr
|
|
expectLen sect, 1
|
|
let def = sect[0]
|
|
let
|
|
lhs = def[0]
|
|
typ = def[1]
|
|
ex = def[2]
|
|
addrTyp = if typ.kind == nnkEmpty: typ else: newTree(nnkPtrTy, typ)
|
|
result = quote do:
|
|
let tmp: `addrTyp` = addr(`ex`)
|
|
template `lhs`: untyped = tmp[]
|
|
result.copyLineInfo(def)
|