android: add script in Android archive to create a SDK

Also, - Move mingw's pkg-support into build-scripts - Add type annotations to python scripts for mypy - ci: use v4 tag of actions/cache - cmake: use PYTHON3_EXECUTABLE for running xxd.py (Python3::Interpreter is not always recognized.)
2025-10-26 12:27:44 +00:00 · 2024-07-31 00:05:54 +02:00
parent 091960441b
commit a1c6f99877
13 changed files with 414 additions and 62 deletions
--- a/build-scripts/pkg-support/android/main.py
+++ b/build-scripts/pkg-support/android/main.py
@@ -0,0 +1,104 @@
+#!/usr/bin/env python
+
+"""
+Create a SDL SDK prefix from an Android archive
+This file is meant to be placed in a the root of an android .aar archive
+
+Example usage:
+```sh
+python SDL3-3.2.0.aar -o /usr/opt/android-sdks
+cmake -S my-project \
+    -DCMAKE_PREFIX_PATH=/usr/opt/android-sdks \
+    -DCMAKE_TOOLCHAIN_FILE=$ANDROID_NDK_HOME/build/cmake/android.toolchain.cmake \
+    -B build-arm64 -DANDROID_ABI=arm64-v8a \
+    -DCMAKE_BUILD_TYPE=Releaase
+cmake --build build-arm64
+```
+"""
+import argparse
+import io
+import json
+import os
+import pathlib
+import re
+import stat
+import zipfile
+
+
+AAR_PATH = pathlib.Path(__file__).resolve().parent
+ANDROID_ARCHS = { "armeabi-v7a", "arm64-v8a", "x86", "x86_64" }
+
+
+def main():
+    parser = argparse.ArgumentParser(
+        description="Convert an Android .aar archive into a SDK",
+        allow_abbrev=False,
+    )
+    parser.add_argument("-o", dest="output", type=pathlib.Path, required=True, help="Folder where to store the SDK")
+    args = parser.parse_args()
+
+    print(f"Creating a SDK at {args.output}...")
+
+    prefix = args.output
+    incdir = prefix / "include"
+    libdir = prefix / "lib"
+
+    RE_LIB_MODULE_ARCH = re.compile(r"prefab/modules/(?P<module>[A-Za-z0-9_-]+)/libs/android\.(?P<arch>[a-zA-Z0-9_-]+)/(?P<filename>lib[A-Za-z0-9_]+\.(?:so|a))")
+    RE_INC_MODULE_ARCH = re.compile(r"prefab/modules/(?P<module>[A-Za-z0-9_-]+)/include/(?P<header>[a-zA-Z0-9_./-]+)")
+    RE_LICENSE = re.compile(r"(?:.*/)?(?P<filename>(?:license|copying)(?:\.md|\.txt)?)", flags=re.I)
+    RE_PROGUARD = re.compile(r"(?:.*/)?(?P<filename>proguard.*\.(?:pro|txt))", flags=re.I)
+    RE_CMAKE = re.compile(r"(?:.*/)?(?P<filename>.*\.cmake)", flags=re.I)
+
+    with zipfile.ZipFile(AAR_PATH) as zf:
+        project_description = json.loads(zf.read("description.json"))
+        project_name = project_description["name"]
+        project_version = project_description["version"]
+        licensedir = prefix / "share/licenses" / project_name
+        cmakedir = libdir / "cmake" / project_name
+        javadir = prefix / "share/java" / project_name
+        javadocdir = prefix / "share/javadoc" / project_name
+
+        def read_zipfile_and_write(path: pathlib.Path, zippath: str):
+            data = zf.read(zippath)
+            path.parent.mkdir(parents=True, exist_ok=True)
+            path.write_bytes(data)
+
+        for zip_info in zf.infolist():
+            zippath = zip_info.filename
+            if m := RE_LIB_MODULE_ARCH.match(zippath):
+                lib_path = libdir / m["arch"] / m["filename"]
+                read_zipfile_and_write(lib_path, zippath)
+                if m["filename"].endswith(".so"):
+                    os.chmod(lib_path, stat.S_IRWXU | stat.S_IRGRP | stat.S_IXGRP | stat.S_IROTH | stat.S_IXOTH)
+
+            elif m := RE_INC_MODULE_ARCH.match(zippath):
+                header_path = incdir / m["header"]
+                read_zipfile_and_write(header_path, zippath)
+            elif m:= RE_LICENSE.match(zippath):
+                license_path = licensedir / m["filename"]
+                read_zipfile_and_write(license_path, zippath)
+            elif m:= RE_PROGUARD.match(zippath):
+                proguard_path = javadir / m["filename"]
+                read_zipfile_and_write(proguard_path, zippath)
+            elif m:= RE_CMAKE.match(zippath):
+                cmake_path = cmakedir / m["filename"]
+                read_zipfile_and_write(cmake_path, zippath)
+            elif zippath == "classes.jar":
+                versioned_jar_path = javadir / f"{project_name}-{project_version}.jar"
+                unversioned_jar_path = javadir / f"{project_name}.jar"
+                read_zipfile_and_write(versioned_jar_path, zippath)
+                os.symlink(src=versioned_jar_path.name, dst=unversioned_jar_path)
+            elif zippath == "classes-sources.jar":
+                jarpath = javadir / f"{project_name}-{project_version}-sources.jar"
+                read_zipfile_and_write(jarpath, zippath)
+            elif zippath == "classes-doc.jar":
+                data = zf.read(zippath)
+                with zipfile.ZipFile(io.BytesIO(data)) as doc_zf:
+                    doc_zf.extractall(javadocdir)
+
+    print("... done")
+    return 0
+
+
+if __name__ == "__main__":
+    raise SystemExit(main())
--- a/build-scripts/pkg-support/android/cmake/SDL3Config.cmake
+++ b/build-scripts/pkg-support/android/cmake/SDL3Config.cmake
@@ -0,0 +1,148 @@
+# SDL CMake configuration file:
+# This file is meant to be placed in lib/cmake/SDL3 subfolder of a reconstructed Android SDL3 SDK
+
+cmake_minimum_required(VERSION 3.0...3.5)
+
+include(FeatureSummary)
+set_package_properties(SDL3 PROPERTIES
+    URL "https://www.libsdl.org/"
+    DESCRIPTION "low level access to audio, keyboard, mouse, joystick, and graphics hardware"
+)
+
+# Copied from `configure_package_config_file`
+macro(set_and_check _var _file)
+    set(${_var} "${_file}")
+    if(NOT EXISTS "${_file}")
+        message(FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist !")
+    endif()
+endmacro()
+
+# Copied from `configure_package_config_file`
+macro(check_required_components _NAME)
+    foreach(comp ${${_NAME}_FIND_COMPONENTS})
+        if(NOT ${_NAME}_${comp}_FOUND)
+            if(${_NAME}_FIND_REQUIRED_${comp})
+                set(${_NAME}_FOUND FALSE)
+            endif()
+        endif()
+    endforeach()
+endmacro()
+
+set(SDL3_FOUND TRUE)
+
+if(SDL_CPU_X86)
+    set(_sdl_arch_subdir "x86")
+elseif(SDL_CPU_X64)
+    set(_sdl_arch_subdir "x86_64")
+elseif(SDL_CPU_ARM32)
+    set(_sdl_arch_subdir "armeabi-v7a")
+elseif(SDL_CPU_ARM64)
+    set(_sdl_arch_subdir "arm64-v8a")
+else()
+    set(SDL3_FOUND FALSE)
+    return()
+endif()
+
+get_filename_component(_sdl3_prefix "${CMAKE_CURRENT_LIST_DIR}/.." ABSOLUTE)
+get_filename_component(_sdl3_prefix "${_sdl3_prefix}/.." ABSOLUTE)
+get_filename_component(_sdl3_prefix "${_sdl3_prefix}/.." ABSOLUTE)
+set_and_check(_sdl3_prefix      "${_sdl3_prefix}")
+set(_sdl3_include_dirs          "${_sdl3_prefix}/include")
+
+set(_sdl3_lib         "${_sdl3_prefix}/lib/${_sdl_arch_subdir}/libSDL3.so")
+set(_sdl3test_lib     "${_sdl3_prefix}/lib/${_sdl_arch_subdir}/libSDL3_test.a")
+set(_sdl3_jar         "${_sdl3_prefix}/share/java/SDL3/SDL3-${SDL3_VERSION}.jar")
+
+unset(_sdl_arch_subdir)
+unset(_sdl3_prefix)
+
+# All targets are created, even when some might not be requested though COMPONENTS.
+# This is done for compatibility with CMake generated SDL3-target.cmake files.
+
+if(NOT TARGET SDL3::Headers)
+    add_library(SDL3::Headers INTERFACE IMPORTED)
+    set_target_properties(SDL3::Headers
+        PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${_sdl3_include_dirs}"
+    )
+endif()
+set(SDL3_Headers_FOUND TRUE)
+unset(_sdl3_include_dirs)
+
+if(EXISTS "${_sdl3_lib}")
+    if(NOT TARGET SDL3::SDL3-shared)
+        add_library(SDL3::SDL3-shared SHARED IMPORTED)
+        set_target_properties(SDL3::SDL3-shared
+            PROPERTIES
+                INTERFACE_LINK_LIBRARIES "SDL3::Headers"
+                IMPORTED_LOCATION "${_sdl3_lib}"
+                COMPATIBLE_INTERFACE_BOOL "SDL3_SHARED"
+                INTERFACE_SDL3_SHARED "ON"
+                COMPATIBLE_INTERFACE_STRING "SDL_VERSION"
+                INTERFACE_SDL_VERSION "SDL3"
+    )
+    endif()
+    set(SDL3_SDL3-shared_FOUND TRUE)
+else()
+    set(SDL3_SDL3-shared_FOUND FALSE)
+endif()
+unset(_sdl3_lib)
+
+set(SDL3_SDL3-static_FOUND FALSE)
+
+if(EXISTS "${_sdl3test_lib}")
+    if(NOT TARGET SDL3::SDL3_test)
+        add_library(SDL3::SDL3_test STATIC IMPORTED)
+        set_target_properties(SDL3::SDL3_test
+            PROPERTIES
+                INTERFACE_LINK_LIBRARIES "SDL3::Headers"
+                IMPORTED_LOCATION "${_sdl3test_lib}"
+                COMPATIBLE_INTERFACE_STRING "SDL_VERSION"
+                INTERFACE_SDL_VERSION "SDL3"
+        )
+    endif()
+    set(SDL3_SDL3_test_FOUND TRUE)
+else()
+    set(SDL3_SDL3_test_FOUND FALSE)
+endif()
+unset(_sdl3test_lib)
+
+if(SDL3_SDL3-shared_FOUND)
+    set(SDL3_SDL3_FOUND TRUE)
+endif()
+
+function(_sdl_create_target_alias_compat NEW_TARGET TARGET)
+    if(CMAKE_VERSION VERSION_LESS "3.18")
+        # Aliasing local targets is not supported on CMake < 3.18, so make it global.
+        add_library(${NEW_TARGET} INTERFACE IMPORTED)
+        set_target_properties(${NEW_TARGET} PROPERTIES INTERFACE_LINK_LIBRARIES "${TARGET}")
+    else()
+        add_library(${NEW_TARGET} ALIAS ${TARGET})
+    endif()
+endfunction()
+
+# Make sure SDL3::SDL3 always exists
+if(NOT TARGET SDL3::SDL3)
+    if(TARGET SDL3::SDL3-shared)
+        _sdl_create_target_alias_compat(SDL3::SDL3 SDL3::SDL3-shared)
+    endif()
+endif()
+
+if(EXISTS "${_sdl3_jar}")
+    if(NOT TARGET SDL3::Jar)
+        add_library(SDL3::Jar INTERFACE IMPORTED)
+        set_property(TARGET SDL3::Jar PROPERTY JAR_FILE "${_sdl3_jar}")
+    endif()
+    set(SDL3_Jar_FOUND TRUE)
+else()
+    set(SDL3_Jar_FOUND FALSE)
+endif()
+unset(_sdl3_jar)
+
+check_required_components(SDL3)
+
+set(SDL3_LIBRARIES SDL3::SDL3)
+set(SDL3_STATIC_LIBRARIES SDL3::SDL3-static)
+set(SDL3_STATIC_PRIVATE_LIBS)
+
+set(SDL3TEST_LIBRARY SDL3::SDL3_test)
--- a/build-scripts/pkg-support/android/cmake/SDL3ConfigVersion.cmake
+++ b/build-scripts/pkg-support/android/cmake/SDL3ConfigVersion.cmake
@@ -0,0 +1,57 @@
+# based on the files generated by CMake's write_basic_package_version_file
+
+# SDL CMake version configuration file:
+# This file is meant to be placed in a lib/cmake/SDL3 subfolder of a reconstructed Android SDL3 SDK
+
+if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../../include/SDL3/SDL_version.h")
+    message(AUTHOR_WARNING "Could not find SDL3/SDL_version.h. This script is meant to be placed in the root of SDL3-devel-3.x.y-VC")
+    return()
+endif()
+
+file(READ "${CMAKE_CURRENT_LIST_DIR}/../../../include/SDL3/SDL_version.h" _sdl_version_h)
+string(REGEX MATCH "#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_version_h}")
+set(_sdl_major "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_version_h}")
+set(_sdl_minor "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_MICRO_VERSION[ \t]+([0-9]+)" _sdl_micro_re "${_sdl_version_h}")
+set(_sdl_micro "${CMAKE_MATCH_1}")
+if(_sdl_major_re AND _sdl_minor_re AND _sdl_micro_re)
+    set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_micro}")
+else()
+    message(AUTHOR_WARNING "Could not extract version from SDL3/SDL_version.h.")
+    return()
+endif()
+
+if(PACKAGE_FIND_VERSION_RANGE)
+    # Package version must be in the requested version range
+    if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
+            OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
+            OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    endif()
+else()
+    if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+        if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
+            set(PACKAGE_VERSION_EXACT TRUE)
+        endif()
+    endif()
+endif()
+
+# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
+if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
+    set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()
+
+include("${CMAKE_CURRENT_LIST_DIR}/sdlcpu.cmake")
+SDL_DetectTargetCPUArchitectures(_detected_archs)
+
+# check that the installed version has a compatible architecture as the one which is currently searching:
+if(NOT(SDL_CPU_X86 OR SDL_CPU_X64 OR SDL_CPU_ARM32 OR SDL_CPU_ARM64))
+    set(PACKAGE_VERSION "${PACKAGE_VERSION} (X86,X64,ARM32,ARM64)")
+    set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()