mirror of
https://github.com/ghostty-org/ghostty.git
synced 2026-08-05 23:28:41 +00:00
e8525c0fd9
This commit represents the majority of the work necessary to upgrade Ghostty to use Zig 0.16.0. Key parts: * In addition to its previous responsibilities, the global state now houses state for global I/O implementations and the process environment. It is now also utilized in the main application along with the C library. Where necessary, global state is isolated from key parts of the implementation (e.g., in libghostty subsystems), and it's expected that this list will grow. * We currently manage our own C translation layer where necessary. In these cases, cImport has been removed in favor of the new external translate-c package. Due to fixes that have needed be made to properly translate the dependencies that were swapped out, as mentioned, we have had to backport fixes from the current translate-c package (and the upstream Arocc dependency). We will host this ourselves until Zig 0.17.0 is released with these fixes. * Where necessary (only a small number of cases), some stdlib code from 0.15.2 (and even from 0.17.0) has been taken, adopted, and vendored in lib/compat. Co-authored-by: Leah Amelia Chen <hi@pluie.me>
93 lines
2.8 KiB
Zig
93 lines
2.8 KiB
Zig
const UnicodeTables = @This();
|
|
|
|
const std = @import("std");
|
|
|
|
/// The exe.
|
|
props_exe: *std.Build.Step.Compile,
|
|
symbols_exe: *std.Build.Step.Compile,
|
|
|
|
/// The output path for the unicode tables
|
|
props_output: std.Build.LazyPath,
|
|
symbols_output: std.Build.LazyPath,
|
|
|
|
pub fn init(b: *std.Build, uucode_tables: std.Build.LazyPath) !UnicodeTables {
|
|
const props_exe = b.addExecutable(.{
|
|
.name = "props-unigen",
|
|
.root_module = b.createModule(.{
|
|
.root_source_file = b.path("src/unicode/props_uucode.zig"),
|
|
.target = b.graph.host,
|
|
.strip = false,
|
|
.omit_frame_pointer = false,
|
|
.unwind_tables = .sync,
|
|
}),
|
|
|
|
// TODO: x86_64 self-hosted crashes
|
|
.use_llvm = true,
|
|
});
|
|
|
|
const symbols_exe = b.addExecutable(.{
|
|
.name = "symbols-unigen",
|
|
.root_module = b.createModule(.{
|
|
.root_source_file = b.path("src/unicode/symbols_uucode.zig"),
|
|
.target = b.graph.host,
|
|
.strip = false,
|
|
.omit_frame_pointer = false,
|
|
.unwind_tables = .sync,
|
|
}),
|
|
|
|
// TODO: x86_64 self-hosted crashes
|
|
.use_llvm = true,
|
|
});
|
|
|
|
if (b.lazyDependency("uucode", .{
|
|
.target = b.graph.host,
|
|
.tables_path = uucode_tables,
|
|
.build_config_path = b.path("src/build/uucode_config.zig"),
|
|
})) |dep| {
|
|
inline for (&.{ props_exe, symbols_exe }) |exe| {
|
|
exe.root_module.addImport("uucode", dep.module("uucode"));
|
|
}
|
|
}
|
|
|
|
const props_run = b.addRunArtifact(props_exe);
|
|
const symbols_run = b.addRunArtifact(symbols_exe);
|
|
|
|
// Generated Zig files have to end with .zig
|
|
const wf = b.addWriteFiles();
|
|
const props_output = wf.addCopyFile(props_run.captureStdOut(.{}), "props.zig");
|
|
const symbols_output = wf.addCopyFile(symbols_run.captureStdOut(.{}), "symbols.zig");
|
|
|
|
return .{
|
|
.props_exe = props_exe,
|
|
.symbols_exe = symbols_exe,
|
|
.props_output = props_output,
|
|
.symbols_output = symbols_output,
|
|
};
|
|
}
|
|
|
|
/// Add the "unicode_tables" import.
|
|
pub fn addImport(self: *const UnicodeTables, step: *std.Build.Step.Compile) void {
|
|
self.props_output.addStepDependencies(&step.step);
|
|
self.symbols_output.addStepDependencies(&step.step);
|
|
self.addModuleImport(step.root_module);
|
|
}
|
|
|
|
/// Add the "unicode_tables" import to a module.
|
|
pub fn addModuleImport(
|
|
self: *const UnicodeTables,
|
|
module: *std.Build.Module,
|
|
) void {
|
|
module.addAnonymousImport("unicode_tables", .{
|
|
.root_source_file = self.props_output,
|
|
});
|
|
module.addAnonymousImport("symbols_tables", .{
|
|
.root_source_file = self.symbols_output,
|
|
});
|
|
}
|
|
|
|
/// Install the exe
|
|
pub fn install(self: *const UnicodeTables, b: *std.Build) void {
|
|
b.installArtifact(self.props_exe);
|
|
b.installArtifact(self.symbols_exe);
|
|
}
|