mirror of
https://github.com/ghostty-org/ghostty.git
synced 2026-05-28 07:45:20 +00:00
eccd07f009
@cImport is going to disappear in Zig 0.17. Its deprecated in Zig 0.16. Let's remove it now. Replace @cImport with addTranslateC across pkg/ packages. Each package now has a c_import.h header that is translated at build time via addTranslateC and exposed as a "cimport" module import. Converted packages: - dcimgui - fontconfig - freetype - glslang - harfbuzz - macos - oniguruma - opengl - sentry - spirv-cross - wuffs Omitted: - gtk4-layer-shell - This has a bit more complexity with how it interacts with GTK headers, so I need to consider this a bit more. - src/ - It'll be cleaner to do this separately.
105 lines
2.8 KiB
Zig
105 lines
2.8 KiB
Zig
const std = @import("std");
|
|
const Allocator = std.mem.Allocator;
|
|
const foundation = @import("../foundation.zig");
|
|
const c = @import("c");
|
|
|
|
pub const URL = opaque {
|
|
pub fn createWithString(str: *foundation.String, base: ?*URL) Allocator.Error!*URL {
|
|
return CFURLCreateWithString(
|
|
null,
|
|
str,
|
|
base,
|
|
) orelse error.OutOfMemory;
|
|
}
|
|
|
|
pub fn createWithFileSystemPath(
|
|
path: *foundation.String,
|
|
style: URLPathStyle,
|
|
dir: bool,
|
|
) Allocator.Error!*URL {
|
|
return @as(
|
|
?*URL,
|
|
@ptrFromInt(@intFromPtr(c.CFURLCreateWithFileSystemPath(
|
|
null,
|
|
@ptrCast(path),
|
|
@intFromEnum(style),
|
|
if (dir) 1 else 0,
|
|
))),
|
|
) orelse error.OutOfMemory;
|
|
}
|
|
|
|
pub fn createStringByReplacingPercentEscapes(
|
|
str: *foundation.String,
|
|
escape: *foundation.String,
|
|
) Allocator.Error!*foundation.String {
|
|
return CFURLCreateStringByReplacingPercentEscapes(
|
|
null,
|
|
str,
|
|
escape,
|
|
) orelse return error.OutOfMemory;
|
|
}
|
|
|
|
pub fn release(self: *URL) void {
|
|
foundation.CFRelease(self);
|
|
}
|
|
|
|
pub fn copyPath(self: *URL) ?*foundation.String {
|
|
return CFURLCopyPath(self);
|
|
}
|
|
|
|
pub extern "c" fn CFURLCreateWithString(
|
|
allocator: ?*anyopaque,
|
|
url_string: *const anyopaque,
|
|
base_url: ?*const anyopaque,
|
|
) ?*URL;
|
|
pub extern "c" fn CFURLCopyPath(*URL) ?*foundation.String;
|
|
pub extern "c" fn CFURLCreateStringByReplacingPercentEscapes(
|
|
allocator: ?*anyopaque,
|
|
original: *const anyopaque,
|
|
escape: *const anyopaque,
|
|
) ?*foundation.String;
|
|
};
|
|
|
|
pub const URLPathStyle = enum(c_int) {
|
|
posix = c.kCFURLPOSIXPathStyle,
|
|
windows = c.kCFURLWindowsPathStyle,
|
|
};
|
|
|
|
test {
|
|
const testing = std.testing;
|
|
|
|
const str = try foundation.String.createWithBytes("http://www.example.com/foo", .utf8, false);
|
|
defer str.release();
|
|
|
|
const url = try URL.createWithString(str, null);
|
|
defer url.release();
|
|
|
|
{
|
|
const path = url.copyPath().?;
|
|
defer path.release();
|
|
|
|
var buf: [128]u8 = undefined;
|
|
const cstr = path.cstring(&buf, .utf8).?;
|
|
try testing.expectEqualStrings("/foo", cstr);
|
|
}
|
|
}
|
|
|
|
test "path" {
|
|
const testing = std.testing;
|
|
|
|
const str = try foundation.String.createWithBytes("foo/bar.ttf", .utf8, false);
|
|
defer str.release();
|
|
|
|
const url = try URL.createWithFileSystemPath(str, .posix, false);
|
|
defer url.release();
|
|
|
|
{
|
|
const path = url.copyPath().?;
|
|
defer path.release();
|
|
|
|
var buf: [128]u8 = undefined;
|
|
const cstr = path.cstring(&buf, .utf8).?;
|
|
try testing.expectEqualStrings("foo/bar.ttf", cstr);
|
|
}
|
|
}
|