re-integrate runtime/ vim-patch:0 #938

Vim runtime files based on 7.4.384 / hg changeset 7090d7f160f7

Excluding:
  Amiga icons (*.info, icons/)
  doc/hangulin.txt
  tutor/
  spell/
  lang/ (only used for menu translations)
  macros/maze/, macros/hanoi/, macros/life/, macros/urm/
      These were used to test vi compatibility.
  termcap
      "Demonstration of a termcap file (for the Amiga and Archimedes)"

Helped-by: Rich Wareham <rjw57@cam.ac.uk>
Helped-by: John <john.schmidt.h@gmail.com>
Helped-by: Yann <yann@yann-salaun.com>
Helped-by: Christophe Badoit <c.badoit@lesiteimmo.com>
Helped-by: drasill <github@tof2k.com>
Helped-by: Tae Sandoval Murgan <taecilla@gmail.com>
Helped-by: Lowe Thiderman <lowe.thiderman@gmail.com>

runtime/compiler/perl.vim

@@ -0,0 +1,47 @@
+" Vim Compiler File
+" Compiler:     Perl syntax checks (perl -Wc)
+" Maintainer:   Christian J. Robinson <heptite@gmail.com>
+" Last Change:  2006 Aug 13
+
+if exists("current_compiler")
+  finish
+endif
+let current_compiler = "perl"
+
+if exists(":CompilerSet") != 2		" older Vim always used :setlocal
+  command -nargs=* CompilerSet setlocal <args>
+endif
+
+let s:savecpo = &cpo
+set cpo&vim
+
+if exists('g:perl_compiler_force_warnings') && g:perl_compiler_force_warnings == 0
+	let s:warnopt = 'w'
+else
+	let s:warnopt = 'W'
+endif
+
+if getline(1) =~# '-[^ ]*T'
+	let s:taintopt = 'T'
+else
+	let s:taintopt = ''
+endif
+
+exe 'CompilerSet makeprg=perl\ -' . s:warnopt . s:taintopt . 'c\ %'
+
+CompilerSet errorformat=
+	\%-G%.%#had\ compilation\ errors.,
+	\%-G%.%#syntax\ OK,
+	\%m\ at\ %f\ line\ %l.,
+	\%+A%.%#\ at\ %f\ line\ %l\\,%.%#,
+	\%+C%.%#
+
+" Explanation:
+" %-G%.%#had\ compilation\ errors.,  - Ignore the obvious.
+" %-G%.%#syntax\ OK,                 - Don't include the 'a-okay' message.
+" %m\ at\ %f\ line\ %l.,             - Most errors...
+" %+A%.%#\ at\ %f\ line\ %l\\,%.%#,  - As above, including ', near ...'
+" %+C%.%#                            -   ... Which can be multi-line.
+
+let &cpo = s:savecpo
+unlet s:savecpo