mirror of
https://github.com/neovim/neovim.git
synced 2025-09-07 11:58:17 +00:00
2cfe4748e5
Instead of deciding provider status in eval_has_provider, move the decision to the provider Vim scripts. Previously, provider loading worked as follows: 1. eval_has_provider() verified provider availability by searching for the provider#providername#Call function and cached this verificaion as a static variable for some providers 2. providers short-circuited on loading to prevent the definition of the Call function (with the exception of the node provider that did not) This commit changes the expected interface between nvim and its providers to facilitate provider reloading, by splitting the verification of the provider from the availability of the Call function. eval_has_provider() now checks for a provider#providername#enabled variable. It is up to the provider script to set this to 0 or 1 accordingly. eval_call_provider() remains unchanged. All providers hosting a Call function were updated to respect this. The clipboard provider now has a Reload function to reload the provider.
48 lines
1.3 KiB
VimL
48 lines
1.3 KiB
VimL
" The Python provider uses a Python host to emulate an environment for running
|
|
" python-vim plugins. :help provider
|
|
"
|
|
" Associating the plugin with the Python host is the first step because plugins
|
|
" will be passed as command-line arguments
|
|
|
|
if exists('g:loaded_python_provider')
|
|
finish
|
|
endif
|
|
let g:loaded_python_provider = 1
|
|
|
|
let [s:prog, s:err] = provider#pythonx#Detect(2)
|
|
let g:provider#python#enabled = !empty(s:prog)
|
|
|
|
function! provider#python#Prog() abort
|
|
return s:prog
|
|
endfunction
|
|
|
|
function! provider#python#Error() abort
|
|
return s:err
|
|
endfunction
|
|
|
|
" The Python provider plugin will run in a separate instance of the Python
|
|
" host.
|
|
call remote#host#RegisterClone('legacy-python-provider', 'python')
|
|
call remote#host#RegisterPlugin('legacy-python-provider', 'script_host.py', [])
|
|
|
|
function! provider#python#Call(method, args) abort
|
|
if s:err != ''
|
|
return
|
|
endif
|
|
if !exists('s:host')
|
|
let s:rpcrequest = function('rpcrequest')
|
|
|
|
" Ensure that we can load the Python host before bootstrapping
|
|
try
|
|
let s:host = remote#host#Require('legacy-python-provider')
|
|
catch
|
|
let s:err = v:exception
|
|
echohl WarningMsg
|
|
echomsg v:exception
|
|
echohl None
|
|
return
|
|
endtry
|
|
endif
|
|
return call(s:rpcrequest, insert(insert(a:args, 'python_'.a:method), s:host))
|
|
endfunction
|