mirror of
https://github.com/neovim/neovim.git
synced 2025-09-07 20:08:17 +00:00
f8fc8f51c0
- fix synopsis highlighting in other locales. Cannot always rely on the first line for the section in some locales; instead, use the file path and explicitly set b:man_sect to the actual section. - eliminate separate s:man_args function - simplify logic: do not reuse buffer content - introduce b:man_default_sects Fixes #5233 - introduce <Plug>(man_vsplit), <Plug>(man_tab) - simplify regexps
38 lines
1.3 KiB
VimL
38 lines
1.3 KiB
VimL
" Maintainer: Anmol Sethi <anmol@aubble.com>
|
|
" Previous Maintainer: SungHyun Nam <goweol@gmail.com>
|
|
|
|
if exists('b:current_syntax')
|
|
finish
|
|
endif
|
|
|
|
syntax case ignore
|
|
syntax match manReference display '[^()[:space:]]\+([0-9nx][a-z]*)'
|
|
syntax match manSectionHeading display '^\S.*$'
|
|
syntax match manTitle display '^\%1l.*$'
|
|
syntax match manSubHeading display '^ \{3\}\S.*$'
|
|
syntax match manOptionDesc display '^\s\+\%(+\|-\)\S\+'
|
|
|
|
highlight default link manTitle Title
|
|
highlight default link manSectionHeading Statement
|
|
highlight default link manOptionDesc Constant
|
|
highlight default link manReference PreProc
|
|
highlight default link manSubHeading Function
|
|
|
|
if b:man_sect =~# '^[23]'
|
|
syntax include @c $VIMRUNTIME/syntax/c.vim
|
|
syntax match manCFuncDefinition display '\<\h\w*\>\ze\(\s\|\n\)*(' contained
|
|
syntax region manSynopsis start='^\%(
|
|
\SYNOPSIS\|
|
|
\SYNTAX\|
|
|
\SINTASSI\|
|
|
\SKŁADNIA\|
|
|
\СИНТАКСИС\|
|
|
\書式\)$' end='^\%(\S.*\)\=\S$' keepend contains=manSectionHeading,@c,manCFuncDefinition
|
|
highlight default link manCFuncDefinition Function
|
|
endif
|
|
|
|
" Prevent everything else from matching the last line
|
|
execute 'syntax match manFooter display "^\%'.line('$').'l.*$"'
|
|
|
|
let b:current_syntax = 'man'
|