mirror of
https://github.com/neovim/neovim.git
synced 2025-10-26 12:27:24 +00:00
66568ed452
runtime: fix :compiler leaving behind a g:makeprg variable (vim/vim#14414)
Problem: :compiler may leave behind a g:makeprg variable after vim/vim#14336.
Solution: Use a script local variable.
b73faa1c02
Also apply previously omitted change to compiler/context.vim.
68 lines
1.8 KiB
VimL
68 lines
1.8 KiB
VimL
" Vim compiler file
|
|
" Compiler: TeX
|
|
" Maintainer: Artem Chuprina <ran@ran.pp.ru>
|
|
" Contributors: Enno Nagel
|
|
" Last Change: 2024 Mar 29
|
|
" 2024 Apr 03 by The Vim Project (removed :CompilerSet definition)
|
|
" 2024 Apr 05 by The Vim Project (avoid leaving behind g:makeprg)
|
|
|
|
if exists("current_compiler")
|
|
finish
|
|
endif
|
|
let s:keepcpo= &cpo
|
|
set cpo&vim
|
|
|
|
" If makefile exists and we are not asked to ignore it, we use standard make
|
|
" (do not redefine makeprg)
|
|
if exists('b:tex_ignore_makefile') || exists('g:tex_ignore_makefile') ||
|
|
\(!filereadable('Makefile') && !filereadable('makefile'))
|
|
" If buffer-local variable 'tex_flavor' exists, it defines TeX flavor,
|
|
" otherwise the same for global variable with same name, else it will be
|
|
" LaTeX
|
|
if exists("b:tex_flavor")
|
|
let current_compiler = b:tex_flavor
|
|
elseif exists("g:tex_flavor")
|
|
let current_compiler = g:tex_flavor
|
|
else
|
|
let current_compiler = "latex"
|
|
endif
|
|
let s:makeprg=current_compiler .. ' -interaction=nonstopmode'
|
|
execute 'CompilerSet makeprg=' .. escape(s:makeprg, ' ')
|
|
else
|
|
let current_compiler = 'make'
|
|
endif
|
|
|
|
" Value errorformat are taken from vim help, see :help errorformat-LaTeX, with
|
|
" addition from Srinath Avadhanula <srinath@fastmail.fm>
|
|
CompilerSet errorformat=%E!\ LaTeX\ %trror:\ %m,
|
|
\%E!\ %m,
|
|
\%+WLaTeX\ %.%#Warning:\ %.%#line\ %l%.%#,
|
|
\%+W%.%#\ at\ lines\ %l--%*\\d,
|
|
\%WLaTeX\ %.%#Warning:\ %m,
|
|
\%Cl.%l\ %m,
|
|
\%+C\ \ %m.,
|
|
\%+C%.%#-%.%#,
|
|
\%+C%.%#[]%.%#,
|
|
\%+C[]%.%#,
|
|
\%+C%.%#%[{}\\]%.%#,
|
|
\%+C<%.%#>%.%#,
|
|
\%C\ \ %m,
|
|
\%-GSee\ the\ LaTeX%m,
|
|
\%-GType\ \ H\ <return>%m,
|
|
\%-G\ ...%.%#,
|
|
\%-G%.%#\ (C)\ %.%#,
|
|
\%-G(see\ the\ transcript%.%#),
|
|
\%-G\\s%#,
|
|
\%+O(%*[^()])%r,
|
|
\%+O%*[^()](%*[^()])%r,
|
|
\%+P(%f%r,
|
|
\%+P\ %\\=(%f%r,
|
|
\%+P%*[^()](%f%r,
|
|
\%+P[%\\d%[^()]%#(%f%r,
|
|
\%+Q)%r,
|
|
\%+Q%*[^()])%r,
|
|
\%+Q[%\\d%*[^()])%r
|
|
|
|
let &cpo = s:keepcpo
|
|
unlet s:keepcpo
|