mirror of
https://github.com/neovim/neovim.git
synced 2026-07-23 17:32:51 +00:00
07c37f6645
Normalize the 15 existing guards to the documented two-level form
get(g:, 'X_recommended_style', get(g:, 'filetype_recommended_style', 1)):
fix the two non-standard "!exists() || != 0" guards (python, arduino) and
tolk's wrong fallback variable, and convert the simple one-level guards.
Add the guard to filetype plugins that set stylistic indentation/format
options without one: aap, abap, ada, cabal, cobol, elixir, falcon,
graphql, heex, idris2, mermaid, occam, racket, scala, swift, tera.
Settings that are required rather than stylistic are left untouched, e.g.
make/gomod/scdoc (mandatory tabs), chatito and vroom (indent mandated by
the format), and the textwidth/formatoptions cases in gitcommit/help/
jjdescription.
Supported by AI.
fixes: vim/vim#20036
closes: vim/vim#20650
1f33732613
Co-authored-by: Christian Brabandt <cb@256bit.org>
Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
70 lines
2.2 KiB
VimL
70 lines
2.2 KiB
VimL
" Vim filetype plugin file
|
|
" Language: Arduino
|
|
" Maintainer: The Vim Project <https://github.com/vim/vim>
|
|
" Ken Takata <https://github.com/k-takata>
|
|
" Last Change: 2024 Apr 12
|
|
" 2024 Jun 02 by Riley Bruins <ribru17@gmail.com> ('commentstring')
|
|
" 2026 Jun 27 by Vim Project (normalize recommended style guard)
|
|
"
|
|
" Most of the part was copied from c.vim.
|
|
|
|
" Only do this when not done yet for this buffer
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
|
|
" Don't load another plugin for this buffer
|
|
let b:did_ftplugin = 1
|
|
|
|
" Using line continuation here.
|
|
let s:cpo_save = &cpo
|
|
set cpo-=C
|
|
|
|
let b:undo_ftplugin = "setl fo< com< ofu< cms< def< inc<"
|
|
|
|
if get(g:, 'arduino_recommended_style',
|
|
\ get(g:, 'filetype_recommended_style', 1))
|
|
" Use the default setting of Arduino IDE.
|
|
setlocal expandtab tabstop=2 softtabstop=2 shiftwidth=2
|
|
let b:undo_ftplugin ..= " et< ts< sts< sw<"
|
|
endif
|
|
|
|
" Set 'formatoptions' to break comment lines but not other lines,
|
|
" and insert the comment leader when hitting <CR> or using "o".
|
|
setlocal fo-=t fo+=croql
|
|
|
|
" These options have the right value as default, but the user may have
|
|
" overruled that.
|
|
setlocal commentstring=/*\ %s\ */ define& include&
|
|
|
|
" Set completion with CTRL-X CTRL-O to autoloaded function.
|
|
if exists('&ofu')
|
|
setlocal ofu=ccomplete#Complete
|
|
endif
|
|
|
|
" Set 'comments' to format dashed lists in comments.
|
|
" Also include ///, used for Doxygen.
|
|
setlocal comments=sO:*\ -,mO:*\ \ ,exO:*/,s1:/*,mb:*,ex:*/,:///,://
|
|
|
|
" When the matchit plugin is loaded, this makes the % command skip parens and
|
|
" braces in comments properly.
|
|
if !exists("b:match_words")
|
|
let b:match_words = '^\s*#\s*if\(\|def\|ndef\)\>:^\s*#\s*elif\>:^\s*#\s*else\>:^\s*#\s*endif\>'
|
|
let b:match_skip = 's:comment\|string\|character\|special'
|
|
let b:undo_ftplugin ..= " | unlet! b:match_skip b:match_words"
|
|
endif
|
|
|
|
" Win32 and GTK can filter files in the browse dialog
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "Arduino Source Files (*.ino, *.pde)\t*.ino;*.pde\n"
|
|
if has("win32")
|
|
let b:browsefilter ..= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter ..= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin ..= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|